Die Inventor FAQ wird unterstützt von:

Inventor FAQ Logo
Einsteigertipps Profitipps Probleme & Abstürze Themensammlungen Newsletter & Feed Alle Artikel Blog unterstützen

20.09.2012

Vault Backup in der Cloud mit Dropbox

imageIch bin begeisterter und zahlender Dropbox Anwender mit einem Online-Speichervolumen von 232,4 GB. Da passt einiges rein. Und ich habe hier Vault Professional 2013 am laufen mit ein paar Tresoren, die gesichert werden wollen. Da ich auf meinem Notebook z.B. für Schulungen autark arbeiten muss, habe ich alles auf dem Notebook laufen: Vault Server, Lizenzserver, Client usw.

Ich möchte natürlich trotzdem meine Daten regelmäßig sichern und zwar platzsparend aber mit einer gewissen Redundanz.

Ich mache das mit Hilfe einer Batch-Datei, 7-Zip, der Windows Aufgabenplanung und Dropbox.

Sichern der Tresore mit einer Batchdatei

Meine Tresore sichere ich mit dieser Batchdatei, die automatisch nach dem eigentlichen Backup aus Vault mit der Console die Daten zippt mit 7-Zip und dabei in einen Ordner in der Dropbox ablegt.

@echo off
REM Wartungsplan unter Windows erstellen und Batch ausfuehren
echo ------------------------------------
echo Vault Server Wartung und Backup
echo (c) Mensch und Maschine Dressler
echo Kontakt: jwagner@dressler.biz
echo ------------------------------------
set tempdir=C:\_TEMP\vault_backup
set backupdir=C:\_ARBEIT\Dropbox\_Firma\Vault Backup
set adms_console=C:\Program Files\Autodesk\ADMS Professional 2013\ADMS Console\Connectivity.ADMSConsole.exe
set ZIP_Filename=vault_backup
set zip_Pfad=C:\Program Files\7-Zip\7z.exe

REM >>> Tresorname, bzw. Datenbankname
set VAULTNAME=MUM
set VAULTLOG=[%VAULTNAME%_log]

REM >>> Einstellen ob Backup gezippt werden soll oder nicht
set zippen=ja
REM wenn nein, dann ist das Tempverz. = Backupverz.
if "%zippen%" == "ja" goto weiter
set tempdir=%backupdir%
:weiter
REM Datum erstellen
set jahr=%date:~-4%
set monat=%date:~-7,2%
set tag=%date:~-10,2%
REM Vormonat bestimmen. Dient dazu alte Logdateien zu löschen
set /a vormonat=%monat%-1

REM Begin Wartungsplan
REM sie auch
http://images.autodesk.com/adsk/files/advanced_config_guide_-_2012.pdf
echo ------------------------------------
echo SQL Wartungsplan
echo ------------------------------------
@echo Tempdb Parameter setzen
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE [tempdb] SET COMPATIBILITY_LEVEL = 100"
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE [tempdb] MODIFY FILE ( NAME = N'tempdev', SIZE = 512000KB )"
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE [tempdb] MODIFY FILE ( NAME = N'templog', SIZE = 512000KB )"
@echo Datenbankkompatibilitaet auf 100 setzen
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE %VAULTNAME% SET COMPATIBILITY_LEVEL = 100"
@echo Wiederherstellungsmodus einfach
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE %VAULTNAME% SET RECOVERY SIMPLE"
@echo Datenbank autom. wachsen
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE %VAULTNAME%  MODIFY FILE (NAME=%VAULTNAME%, FILEGROWTH=100MB)"
@echo LOG-Datei Groesse setzen
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE %VAULTNAME% MODIFY FILE ( NAME = %VAULTLOG%, SIZE = 512KB )"
@echo Autoclose auf falsch setzen
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "ALTER DATABASE %VAULTNAME% SET AUTO_CLOSE OFF WITH NO_WAIT"
@echo Neuindixierung %VAULTNAME% Datenbank
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "USE %VAULTNAME% DECLARE tableCursor CURSOR FOR SELECT NAME FROM sysobjects WHERE xtype in('U') DECLARE @tableName nvarchar(128) OPEN tableCursor FETCH NEXT FROM tableCursor INTO @tableName WHILE @@FETCH_STATUS = 0 BEGIN DBCC DBREINDEX(@tableName, '') FETCH NEXT FROM tableCursor INTO @tableName END CLOSE tableCursor DEALLOCATE tableCursor"
@echo Aktualisiere Statistik bei %VAULTNAME% Datenbank
sqlcmd -U sa -P AutodeskVault@26200 -S".\AutodeskVault" -Q "EXEC sp_updatestats"
REM ENDE Wartungsplan

if "%zippen%" == "nein" goto temp_ok
echo ------------------------------------
echo loesche alte TEMP-Daten
echo ------------------------------------
RMDIR /S /Q "%tempdir%"
md "%tempdir%"
:temp_ok

echo ------------------------------------
echo loesche alte Log-Dateien
echo ------------------------------------
del "%backupdir%\backuplog_%vormonat%_%jahr%.txt"

echo ------------------------------------
echo Alte Versionen in Vault bereinigen
echo ------------------------------------
REM >>> -KEEPVERS1 -MINAGE0 anpassen
REM siehe auch
http://wikihelp.autodesk.com/Vault/enu/2012/Help/02._Working_with_Vault/02._Vault_Server/1013CommandLineServerCo
"%adms_console%" -Opurge -N%VAULTNAME% -KEEPVERS1 -MINAGE0 -EXCLCMT"" -VUadministrator -VP

echo ------------------------------------
echo Vault sichern
echo ------------------------------------
REM Logindaten anpassen
REM siehe auch
http://wikihelp.autodesk.com/Vault/enu/2012/Help/02._Working_with_Vault/02._Vault_Server/1013CommandLineServerCo
"%adms_console%" -Obackup -B"%tempdir%" -VU"Administrator" -VP -DBSC -S -L"%backupdir%\backuplog_%monat%_%jahr%.txt"

REM mit Zippen, dann weiter sonst weiter ab Ende
if "%zippen%" == "nein" goto Ende
echo ------------------------------------
echo Loesche alte ZIP-Sicherung
echo ------------------------------------
del /F /Q "%backupdir%\%ZIP_Filename%*.zip"

echo ------------------------------------
echo zippe Backup innerhalb der Dropbox
echo ------------------------------------
REM benötigt 7-Zip
http://www.7-zip.de/
"%zip_Pfad%" a "%backupdir%\%ZIP_Filename%_%date%.zip" "%tempdir%\*"

echo ------------------------------------
echo loesche TEMP-Daten
echo ------------------------------------
RMDIR /S /Q "%tempdir%"

:Ende
REM >>>> Pause ggf. auskommentieren
echo ------------------------------------
echo Fertig!
echo ------------------------------------
REM Pause

Cloudbackup mit Dropbox

Sobald das Sichern und zippen der Daten fertig ist, sichert Dropbox diese Zip-Datei automatisch in der Cloud.

image

Die alte Zip-DAtei wird gelöscht, kann aber dank der Sicherung in der Cloud ggf. wieder hergestellt werden.

image

Standardmäßig werden die Daten nach 30 Tagen gelöscht, mit aktivem Packrat Feature in Dropbox werden die Datei nie gelöscht und ich kann auch auf Sicherungen von vor ein paar Jahren zurückgreifen.image

Batchdatei ausführen mit der Windows Aufgabenplanung

Die Batchdatei wird bei mir jeden Freitag um 12.30 ausgeführt (Beginn Mittagspause) und ist dann um 13.30 fertig, wenn ich mich wieder an die Arbeit mache.

image

Keine Kommentare:

Kommentar veröffentlichen

War der Beitrag hilfreich oder hast du eine Ergänzung dazu?
Ist noch eine Frage offen?
Ich freue mich auf deine Rückmeldung!

Related Posts Plugin for WordPress, Blogger...
Inventor FAQ Newsletter. Emailadresse: