iLogic: Zwischen verschiedenen Detailgenauigkeiten wechseln

Wie kann ich einen Schaltfläche bauen, mit der ich zirkulär durch bestimmte Detailgenauigkeiten (LOD) wechseln kann, so wie im Bild zu sehen:

Dim oDoc As Inventor.AssemblyDocument 
oDoc = ThisDoc.Document

Dim oAsmCompDef As ComponentDefinition
oAsmCompDef = oDoc.ComponentDefinition

Dim aktivesLOD As String = oAsmCompDef.RepresentationsManager.ActiveLevelOfDetailRepresentation.Name

Select Case aktivesLOD
	'LOD NAMEN ANPASSEN!!
Case "Ersatz1"
	LOD = "Ersatz2"
Case "Ersatz2"
	LOD = "Ersatz3"
Case "Ersatz3"
	LOD = "Ersatz1"
End Select

Try
	oAsmCompDef.RepresentationsManager.LevelOfDetailRepresentations.Item(LOD).Activate(True)
Catch
	MsgBox ("Fehler beim umstellen auf LOD " & LOD)
End Try

'oDoc.Update
oDoc.Update2

Zum Aufruf mittels Schaltfläche ein Formular erstellen und dort die Regel rein ziehen.

[Quelle. Danke an Aleks für sein Codebeispiel das als Basis diente]

VBA/iLogic: Auf Zeichnung Abwicklung und skizziertes Symbol einfügen wenn Erstansicht ein Blechteil ist

iLogic-Code

Imports Inventor.ViewOrientationTypeEnum
Imports Inventor.DrawingViewStyleEnum

Sub Main()
    Dim Zeich As DrawingDocument
     Zeich = ThisApplication.ActiveDocument
    
    Dim oSheet As Sheet
     oSheet = Zeich.ActiveSheet
    'Modell er esten Ansicht ermitteln
    Dim Modell As Document
     Modell = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument
    
    'Prüfen ob Modell Blechteil ist
    Dim sDocumentSubType As String
    sDocumentSubType = Modell.SubType
    
    If sDocumentSubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then
        'Abwicklungsansicht erstellen
         AddFlatPatternDrawingView (Modell.FullFileName)
         
         'Symbol ergänzen
         Dim SymName As String
         SymName = "CAD-CAM"
        Dim oSketchedSymbolDef As SketchedSymbolDefinition
         oSketchedSymbolDef = Zeich.SketchedSymbolDefinitions.Item(SymName)
        
        Dim oTG As TransientGeometry
         oTG = ThisApplication.TransientGeometry
        
        Dim oSketchedSymbol As SketchedSymbol
         oSketchedSymbol = Zeich.ActiveSheet.SketchedSymbols.Add(oSketchedSymbolDef, oTG.CreatePoint2d(15, 5), 0, 1)
         
    Else
     Exit Sub
    End If
    
End Sub

Public Sub AddFlatPatternDrawingView(Modellpfad As String)
    '  a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
     oDrawDoc = ThisApplication.ActiveDocument

    ' a reference to the active sheet.
    Dim oSheet As Sheet
     oSheet = oDrawDoc.ActiveSheet

    ' Create a new NameValueMap object
    Dim oBaseViewOptions As NameValueMap
     oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap

    '  the options to use when creating the base view.
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Open the sheet metal document invisibly
    Dim oModel As Document
     oModel = ThisApplication.Documents.Open(Modellpfad, False)

    ' Create the placement point object.
    Dim oPoint As Point2d
     oPoint = ThisApplication.TransientGeometry.CreatePoint2d(25, 20)

    ' Create a base view.
    Dim oBaseView As DrawingView
     oBaseView = oSheet.DrawingViews.AddBaseView(oModel, oPoint, 0.3, _
    kDefaultViewOrientation, kHiddenLineRemovedDrawingViewStyle, _
    , , oBaseViewOptions)
End Sub

VBA-Code

Private Sub WennBlechDannAbwicklung()
    Dim Zeich As DrawingDocument
    Set Zeich = ThisApplication.ActiveDocument
    
    Dim oSheet As Sheet
    Set oSheet = Zeich.ActiveSheet
    'Modell er esten Ansicht ermitteln
    Dim Modell As Document
    Set Modell = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument
    
    'Prüfen ob Modell Blechteil ist
    Dim sDocumentSubType As String
    sDocumentSubType = Modell.SubType
    
    If sDocumentSubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then
        'Abwicklungsansicht erstellen
         AddFlatPatternDrawingView (Modell.FullFileName)
         
         'Symbol ergänzen
         Dim SymName As String
         SymName = "CAD-CAM"
        Dim oSketchedSymbolDef As SketchedSymbolDefinition
        Set oSketchedSymbolDef = Zeich.SketchedSymbolDefinitions.Item(SymName)
        
        Dim oTG As TransientGeometry
        Set oTG = ThisApplication.TransientGeometry
        
        Dim oSketchedSymbol As SketchedSymbol
        Set oSketchedSymbol = Zeich.ActiveSheet.SketchedSymbols.Add(oSketchedSymbolDef, oTG.CreatePoint2d(0, 0), 0, 1)
         
    Else
     Exit Sub
    End If
    
End Sub

Public Sub AddFlatPatternDrawingView(Modellpfad As String)
    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    'Set a reference to the active sheet.
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet

    ' Create a new NameValueMap object
    Dim oBaseViewOptions As NameValueMap
    Set oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap

    ' Set the options to use when creating the base view.
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Open the sheet metal document invisibly
    Dim oModel As Document
    Set oModel = ThisApplication.Documents.Open(Modellpfad, False)

    ' Create the placement point object.
    Dim oPoint As Point2d
    Set oPoint = ThisApplication.TransientGeometry.CreatePoint2d(25, 20)

    ' Create a base view.
    Dim oBaseView As DrawingView
    Set oBaseView = oSheet.DrawingViews.AddBaseView(oModel, oPoint, 1, _
    kDefaultViewOrientation, kHiddenLineRemovedDrawingViewStyle, _
    , , oBaseViewOptions)
End Sub

Bemerkungen

Das ist natürlich nur ein grobes Codegerüst:

• Hat das Blech noch keine Abwicklung scheitert der Code. Da müsste man ggf. prüfen, ob eine Abwicklung vorhanden ist und wenn nicht dann eine erstellen
• Der Ansichtsmaßstab der Abwicklung und deren Position auf dem Blatt müsste abhängig von der Blechgröße und Blattgröße noch ermittelt werden
• ggf. muss die Position des Symbols angepasst werden

Links zum Thema

VBA Code in iLogic Code "umwandeln"

[Quelle]

iLogic Regel automatisch beim Speichern ausführen [Tool] [Update 3]

Update 10.1.2019: Das Tool ist veraltet. Ersatz gibt es in der Inventor FAQ Toolbox (nur für MUM Kunde verfügbar): Beim Speichern einer Inventordatei (inkl. Komponenten bei Baugruppen) eine externe iLogicregel ausführen (Toolbox).

Seit Inventor 2018 gibt es auch einen global definierbaren Regelauslöser. Siehe dazu  Inventor-Programmcode (iLogic und VBA) abspeichern und ausführen (lassen) – Möglichkeiten und Fallstricke

---

Update 6.3.2013: Das Tool sollte auch unter Inventor 2013 funktionieren. Die 2012-Version aus dem Download unten installieren, den Inventor einmal starten und schließen und dann die REG-Datei ausführen.

Update 1.7.2011: Jetzt auch für Inventor 2012! Downloadlink geändert.

Unser Azubi Markus hat ein weiteres Plug-In für den Inventor programmiert: das iLogic Run on Save Tool für Inventor 2010 & 2011 & 2012 (32- & 64-Bit). Das Tool führt beim Speichern eine Externe Regel mit dem Namen des gespeicherten Dokumenttyps (IPT,IAM,IDW,IPN) aus. Anders als beim “Ereignisauslöser” muss der Auslöser nicht in der eigentlichen Datei definiert sein. Das Tool führt die externe Regel deren Namen=Dateiendung ist aus, wenn gespeichert wird.

Installation

1. Programm als ZIP Datei herunterladen. http://goo.gl/HljZo (share jetzt über Dropbox, hoffe, das klappt jetzt für alle!)
   
2. Inventor schließen, RAR Datei öffnen und die gewünschte Version doppelklicken
   
   
   
3. Den angegeben Pfad beibehalten und installieren
   
   
   
4. Unter Extras > Zusatzmodule kann im Inventor geprüft werden, ob das Tool korrekt installiert und registriert wurde.
   
   
   

Einrichtung
für jeden gewünschten Dokumenttyp (IPT, IAM, IDW, DWG, IPN) eine externe Regel mit dem Namen=Dateiendung erstellen. Bei einer Regel für eine IPT als eine externe Regel mit Namen IPT erstellen.


Wird nun ein Bauteil gespeichert, führt das iLogic Run on Save Tool die externe iLogic-Regel mit dem Regelnamen = Dateiendung aus. Sollte zu einem Dokumenttyp keine Regel existieren passiert nichts.
Das Tool wird “as is” zur Verfügung gestellt und beinhaltet keinen Support oder sonstige Unterstützung. Feedback bitte direkt an den Kollegen Markus oder als Kommentar hier im Beitrag.
Wer wissen will, was iLogic ist und was es kann, der kann hier mehr erfahren.

iLogic: Aus dem Modell eine Regel in der Zeichnung aufrufen

Oder allgemeiner: Aus einer Datei eine Regel in der einer anderen Datei aufrufen. Hier der Quellcode mit Kommentaren zur Erklärung.

==>

Die ilogic Regel Regel_IDW in der IAM soll die Regel Meldung_IDW in der zugehörigen gleichnamigen Zeichnung ausführen.

'Extension zu Zeichnung und Regelname in der Zeichnung anpassen
Dim Ext As String = "dwg"
Dim Regelname As String = "Meldung_IDW"
'---------------------------------
'Hier wird der Pfad der Zeichnung erzeugt aus dem Dateipfad des aktuellen Modells zzgl. 
'der Dateiendung im der Var. Ext
'Der Pfad kann auch absolut angegeben werden, wenn er nicht ais dem Pfad des aktuellen
'Dokuments zusammengesetzt werden kann.
'Bsp: Dim DWGPfad As String = "c:\Zeichnungen\xyz.ipt"
Dim DWGPfad As String = ThisDoc.PathAndFileName(False) & "." & Ext
'Die Var. geladen wird benötigt, um die Zeichung ggf. zu laden, falls sie nicht schon
'geladen ist.
Dim geladen As Boolean = False
Dim iLogicAuto = iLogicVb.Automation
Dim Doc As Document
For Each Doc In ThisApplication.Documents.VisibleDocuments
	If Doc.FullFileName = DWGPfad Then
		oDoc = Doc	
		geladen = True
		Exit For
	End If
Next
If gelanden = False Then oDoc = ThisApplication.Documents.Open(DWGPfad)
iLogicAuto.RunRule(oDoc, Regelname)

Inventor-Programmcode (iLogic und VBA) abspeichern und ausführen (lassen) – Möglichkeiten und Fallstricke

In letzter Zeit bin ich wieder im Autodesk Inventor Forum aktiv nach einer Pause, in der ich mich mit anderen Themen beschäftigt habe. Nun also mal wieder mehr Inventor "Freizeitbeschäftigung".  Dort sind nur ein paar Fragen aufgefallen, bei denen es immer darum ging, Programmcode (meist iLogic) abzuspeichern und dann auch noch automatisch bei einem bestimmten Ereignis auszuführen. Ein paar Beispiele:

• Beim Speichern soll geprüft werden, ob Komponenten einer Baugruppe ein iProperty mit einem bestimmten Wert enthalten sind.
• Beim Speichern sollen iProperties abgefragt werden.

Bei beiden (und allen anderen gleichartigen Fragestellungen) geht es immer um zwei Aufgabenstellungen:

1. Es gibt einen Programmcode, der ausgeführt werden soll
2. Das Ausführen des Programms soll über ein Ereignis erfolgen, z.B. immer vor dem Speichern

Programmcode erstellen

In meinen Programmieranleitungen habe ich im ersten Beitrag die verschiedenen Möglichkeiten erwähnt, die es erlauben, den Inventor über eine Programm zu automatisieren.

• iLogic
• VBA
• Add-In / externes Programm

Die Einsteiger unter den Hobbyprogrammierern werden sich auf iLogic und VBA konzentrieren, da hier die Programmierumgebungen direkt im Inventor integriert sind. Es sind keine anderen Programm notwendig, die wieder neues Know How (neben dem beherrschen der eigentlichen Programmiersprache) benötigen.

Hier der iLogic Codeeditor:

 

Die VBA IDE:

Im Gegensatz dazu das MS Visual Studio in der kostenlosen Express Edition, das heruntergeladen, installiert und eben auch bedient werden können muss:

Und was soll den nun angewendet werden? Einfache Antwort: Das hängt davon ab ;)

Parameter eines Bauteiles beim Einfügen in eine Baugruppe per Dialog abfragen (iLogic)

Wie kann ich erreichen, das beim Einfügen eines Bauteiles in einem Baugruppe der Wert eines Parameters abgefragt wird?

1. Im Bauteil eine iLogic-Formular erstellen in dem der (oder die) Parameter abgefragt werden
   
   
   
   
2. ein iLogic Regel anlegen, die das Formular aufruft
   
   
3. Ereignisauslöser aktivieren der beim einer neuen Datei die Regel ausführt
   Dazu im Ribbon Verwalten > iLogic den Ereignisauslöser aufrufen
   
   
   
   
4. Datei als Vorlage speichern
   
   

Anwendung: In einer Baugruppe eine neue IPT auf Basis der Vorlage erstellen. Nach dem Platzieren wird der Dialog angezeigt.

Alternative Möglichkeit: iParts

iLogic: Parameter aus einer Baugruppe in Bauteilen verwenden

Ausgangssituation: In einer Baugruppe gibt es einen Parameter Anzahl, der über ein iLogic-Form im Wert geändert werden kann.

==>

Wird der Parameterwert über den Schieberegler geändert, soll der Wert innerhalb der Bauteile in der Baugruppe auch geändert werden. Die Parameter in den Bauteilen heißt ebenfalls Anzahl. Dieser Parameter wird ebenfalls in beiden Bauteilen in Features verwendet, z.B. in der Runden Anordnung und der Drehung.

Es soll nun erreicht werden, das bei einer Änderung des Parameters in der IAM die Parameter in den IPTs geändert wird. Das ergibt dann folgendes Verhalten (die zufällige Farbänderung der Komponenten in der IAM wird ebenfalls bei der Parameteränderung durchgeführt):

iLogic: Skizzenumfang auslesen und in Benutzer-iProperty schreiben

'Variablen 
Dim Skizzenname As String
Dim Umfang As Double 
Dim iPropName As String

'Variablen Werte zuweisen
Skizzenname = "Skizze1"
'Hier wird die Skizzenlänge aus der Skizze mit dem in der Var. Skizzenname
'hinterlegten Skizze ausgelesen
Umfang = Measure.Perimeter(Skizzenname)
'Diese Var. enthält den Benutzer-iProp.-Name den ich aus dem Skizzennamen
'und dem Suffix _Umfang zusammensetze
iPropName = Skizzenname & "_Umfang"

'Wert ausgeben und in iProp. schreiben
MsgBox (Umfang)
iProperties.Value("Custom", iPropName)= Umfang

 

Download Beispiel-IPT (Inventor 2019)

Flächen, Kanten und Scheitelpunkten Namen geben und in iLogic nutzen

In Inventor 2019 können Flächen, Körperkanten und Punkte Namen gegeben werden. Dazu das gewünschte Geometrieobjekt anwählen > Rechtsklick > Namen zuweisen

  

Ergebnis:

Warum das Ganze?

Inventor 2019.1: Logging in iLogic (iLogic-Protokoll)

Das Update 1 für Inventor 2019 bringt eine Art Logging-Funktion in iLogic. Das Prinzip ist recht einfach:

1. Im Code können Ausgabetexte in einer bestimmten Hierarchiestufung definiert werden.
2. Meldungen, die für diese oder eine niederrangige Hierarchiestufe im iLogiceditor konfiguriert sind, werden ausgegeben.

Hört sich komplizierter an, als es ist.

Das iLogic-Protokoll anzeigen

Im Browser das Register "iLogic-Protokoll" einblenden

Im iLogic-Quelltext die Protokollausgabe definieren

Es gibt verschiedene Hierarchiestufen der Meldungsrelevanz, also es gibt sehr wichtige Meldungen und z.B. nur solche, die als Information gedacht sind. Unten über die Auswahlliste kann angegeben werden, welche Hierarchiestufe im iLogic-Protokoll anzeigt werden soll. Das geht von "None" für überhaupt keine Log-Ausgaben bis zu Trace, das alle Logger-Ausgaben und weitere Infos in im iLogic-Protokoll anzeigt.

Ausgabelevel Warn: Es wird nur die Meldung hinter Logger.Warn und alle niederwertigeren Meldungsstufen (also Fatal und Error) angezeigt.

=>

Ausgabelevel Trace: Das ist der höchste Level. Alle Meldungen werden ausgegeben, d.h. alles, was Trace ist oder darunter (Debug, Info, Warn, Error, Fatal).

==>

Wird die Protokollebene "None" gewählt, ist die Ausgabe komplett deaktiviert.

Ausgabe im Code ergänzen

Der Befehl zur Ausgabe im Protokoll lautet logger. Dank der automatischen Vervollständigung genügt es logger. zu schreiben und dann aus der Liste die Protokollebene zu wählen.

Dann noch ne Klammer und den Text ggf. mit der Vernüpfung mit einer Variable wie in diesem Beispielen:

x = 10
y = 20
z = x + y
msgbox(z)
Logger.Info("Varwert x=" & x)
Logger.Debug("Displayname:" & ThisDoc.Document.DisplayName)
Logger.Fatal("Fataler Fehler aufgetretten!")
Logger.Warn("WARNUNG, ALLES IM EIMER!")
'Array anzeigen
Dim a(2) As Object
a(1) = "HALLO"
a(2) = "WELT"
Logger.Debug("Array anzeigen {1} und dann {2}", a)

Ausgabe:

(Man beachten auch die Ausgabe der Arraywerte)

Protokoll löschen und exportieren…

…geht über das Kontextmenü.

Ausgeblendet (gelöschte) Logeinträge können über die Auswahl "Frühere Meldungen anzeigen" wieder eingeblendet werden.

iLogic: externe Regeln global verfügbar machen (Einstellungen)

Inventor lässt sich über vier Wege automatisieren:

1. VBA (Programmierkurs VBA)
2. iLogic (iLogic-Beiträge)
3. Add-In
4. externes Programm, das auf den Inventor zugreift

Heute ist das automatisieren über iLogic recht beliebt, was wohl auch daran liegt, das die Erstellung des Programmcodes relativ einfach durchführbar ist. Wobei das debuggen eines iLogic-Codes immer noch nicht so komfortabel ist, wie bei der Programmierung in VBA. Es kann nützlich ein, die ersten Versuche in VBA zu machen und den VBA-Code dann, wenn er funktioniert, in iLogic zu übertragen. Siehe dazu VBA Code in iLogic Code "umwandeln"

Externe Regeln auf allen Arbeitsplätzen zur Verfügung stellen

Wenn Automatismen unabhängig von der gerade geöffneten Datei zur Verfügung stehen sollen, nutzen Regel, die in einer Datei gespeichert werden, nichts. Es muss auf externe iLogic-Regeln zugegriffen werden. Externe Regeln sind Textdateien, die den iLogic Programmcode enthalten. Damit Inventor automatisch auf eine Sammlung externen Regeln zugreift, müssen:

1. die Regeln in einer Textdatei mit der Endung .iLogicVb gespeichert sein
   
   
2. Im Inventor der Pfad zu diesen Dateien konfiguriert sein.
   
   

Excel-Liste aller tolerierten Maße eines Bauteiles erstellen und in Excel exportieren

Gibt es eine Möglichkeit, alle in einem Bauteil definierten Toleranzen auf einen Blick anzuzeigen, ohne dass man sich jede Bohrung und Skizze einzeln vornehmen muss?

Das iLogic-Programm anbei erstellt eine CSV-Datei mit den Parametern, die mit Toleranzen versehen sind.

und hebt die Skizzen und Feature hervor, in den die Parameter enthalten sind.

imports System.IO
Sub Main()
	Dim oDoc As PartDocument
	oDoc = ThisApplication.ActiveDocument
	
	Dim  Dateiname As String = "C:\temp\" & ThisDoc.FileName(False) & ".csv"
	
	If System.IO.File.Exists(Dateiname) Then System.IO.File.Delete(Dateiname)
	
	Dim oFeature As PartFeature
	Dim oFeatureDim As FeatureDimension
	
	Dim Skizze As PlanarSketch
	Dim SkizzeBem As Object
	For Each oFeature In oDoc.ComponentDefinition.Features 
		
		For Each oFeatureDim In oFeature.FeatureDimensions
			Call DisplayToleranceInfo(oFeature, oFeatureDim.parameter, Dateiname)
		Next 
	Next	
	
	For Each Skizze In oDoc.ComponentDefinition.Sketches 
		
		For Each SkizzeBem In Skizze.DimensionConstraints
			Call DisplayToleranceInfo(Skizze, SkizzeBem.Parameter, Dateiname)
			Next	   	     
		Next	
		process.Start(Dateiname)
End Sub
Private Sub DisplayToleranceInfo(Obj As Object, Param As Parameter, Dateiname As String) 
	
	Dim tol As Tolerance
	tol = Param.Tolerance
	
	
	If Param.Tolerance.HoleTolerance <> "" Then 
		Using sw As New StreamWriter(System.IO.File.Open(Dateiname, FileMode.Append))
				sw.WriteLine(Obj.Name &";" & Param.Name & ";" & Param.Expression & ";" & Param.Tolerance.HoleTolerance  & ";" & Math.Round(tol.Upper,4) & ";" & Math.Round(tol.Lower,4)  & ";" &  ";" & Math.Round(Param.Value * 10 + tol.Upper,4) & ";" & Math.Round(Param.Value *10 + tol.Lower,4)) '& ";" & Param.Tolerance.ToleranceType
		End Using
		ObjSichtbar(Obj)
	End If
	
	If Param.Tolerance.ShaftTolerance <> "" Then 
		Using sw As New StreamWriter(System.IO.File.Open(Dateiname, FileMode.Append))
				sw.WriteLine(Obj.Name &";" & Param.Name & ";" & Param.Expression & ";" &  Param.Tolerance.ShaftTolerance  & ";" & Math.Round(tol.Upper,4) & ";" & Math.Round(tol.Lower,4)  & ";" &  ";" & Math.Round(Param.Value * 10 + tol.Upper,4) & ";" & Math.Round(Param.Value * 10 + tol.Lower,4)) '& ";" & Param.Tolerance.ToleranceType
		End Using
		ObjSichtbar(Obj)
	End If
End Sub
Private Sub ObjSichtbar(obj As Object)
	Dim oDoc As PartDocument = ThisApplication.ActiveDocument 
	Dim objType As ObjectTypeEnum
	objType = obj.Type

	If objType = ObjectTypeEnum.kPlanarSketchObject Then
		Call oDoc.SelectSet.Select(obj)	
	Else
		Call oDoc.SelectSet.Select(obj)	
	End If
	
End Sub

[Quelle]

iLogic: Texte aller gleichnamigen angeforderten Eingaben in skizzierten Symbolen ändern

so kannst man die angeforderte Eingabe aller Symbole, bei der die angeforderte Eingabe "Text_sym" heißt auf einen abgefragten Wert setzen.

Symboltext = InputBox("Wert Symboltext", "Symboltext", "-")
For Each oSS As SketchedSymbol In ActiveSheet.Sheet.SketchedSymbols

		Dim oTB As TextBox
		For Each oTB In oSS.Definition.Sketch.TextBoxes
		  If oTB.Text = "Text_Sym" Then
		    Call oSS.SetPromptResultText(oTB, Symboltext)
		  End If
		Next
Next 

Inventor 2018 IDW: 171127120834332 skizziertes Symbol - Texte kopieren.idw ‏128 KB

[Quelle]